Forum Debian Users Gang

#zshrc - ZSH config file
#author - svl
#Some functions comes from zsh doc, some are from other users conf files, that you can find in the web

#zsh history
export HISTSIZE=4096
export HISTFILE="$HOME/.zsh_history"
export SAVEHIST=${HISTSIZE}

#set some variables
export EDITOR=${EDITOR:-vim}
export PAGER=most
#export MAIL=${MAIL:-/var/mail/$USER}

#if we don't set $SHELL then aterm, rxvt,.. will use /bin/sh or /bin/bash :-/
export SHELL='/bin/zsh'
#force OpenOffice to use GTK2 theme [ gnome/kde ]
export OOO_FORCE_DESKTOP=gnome
export MENUCONFIG_COLOR=mono

#antialiasing with GTK/QT
export QT_XFT=1
export GDK_USE_XFT=1

umask=0020
#umask 066
#if root set unmask to 022 to prevent new files being created group and world writable
if [ "`id -u`" = "0" ]; then
    umask 022
fi


#$bindkey command list of all bindkeys in system, $man zshzle
#use emacs style per default
bindkey -e

bindkey `tput khome` beginning-of-line >/dev/null 2>&1
bindkey `tput kend` end-of-line >/dev/null 2>&1
bindkey `tput kich1` quoted-insert >/dev/null 2>&1
bindkey `tput kdch1` delete-char >/dev/null 2>&1
bindkey `tput kpp` up-history >/dev/null 2>&1
bindkey `tput knp` end-of-history >/dev/null 2>&1
bindkey `tput kcuu1` history-beginning-search-backward >/dev/null 2>&1
bindkey `tput kcud1` history-beginning-search-forward >/dev/null 2>&1

#smart history search for screen
bindkey '^[[A' up-history >/dev/null 2>&1
bindkey '^[[B' end-of-history >/dev/null 2>&1
bindkey '^[[A' history-beginning-search-backward >/dev/null 2>&1
bindkey '^[[B' history-beginning-search-forward >/dev/null 2>&1

#konsole
#bindkey '^[[1;5C' forward-word
#bindkey '^[[1;5D' backward-word
#urxvt
bindkey '^[Od' backward-word
bindkey '^[Oc' forward-word

autoload -Uz compinit colors
compinit -C 

#prompt
autoload -U promptinit
promptinit
#promptinit; prompt 'prompt -l'

#prompt colors

local RED=$'%{\e[1;31m%}'
local GREEN=$'%{\e[1;32m%}'
local YELLOW=$'%{\e[1;33m%}'
local BLUE=$'%{\e[1;34m%}'
local PINK=$'%{\e[1;35m%}'
local CYAN=$'%{\e[1;36m%}'
local GREY=$'%{\e[1;30m%}'
local NORMAL=$'%{\e[0m%}'
local TEST=$'%{\e[1;37m%}'

#prompt settings
#%40<...< -shows 40% of path 
#if [[ `whoami` == root ]]; then
#    PS1="%{$RED%}[%{$RED%}%n%{$NORMAL%}@%{$TEST%}%m %30<...< %{$NORMAL%}%~]%(!.#.%\$) "
#    RPS1="%{$GREEN%}%T%{$NORMAL%}"
#    RPS1="%{$(echotc UP 1)%}%{$GREEN%}%T%{$NORMAL%}%{$(echotc DO 1)%}"
#else
#    PS1="%{$GREEN%}[%{$GREEN%}%n%{$NORMAL%}@%{$TEST%}%m %30<...< %{$NORMAL%}%~]%(!.#.%\$) "
#    RPS1="%{$GREEN%}%T%{$NORMAL%} "
#    RPS1="%{$(echotc UP 1)%}%{$GREEN%}%T%{$NORMAL%}%{$(echotc DO 1)%}"
#fi


#PS1="%T
#%{$GREEN%}[%{$GREEN%}%n%{$NORMAL%}@%{$TEST%}%m %30<...< %{$NORMAL%}%~]%(!.#.%\$) "

#local blue_op="%{$GREEN%}[%{$reset_color%}"
#local blue_cp="%{$NORMAL%}%{$reset_color%}"
#local path_p="${BLUE%}%~${blue_cp}"
#local user_host="${GREEN}%n@%{$TEST%}%m${blue_cp}"
#local ret_status="${RED}%?${blue_cp}"
#local time="${BLUE}%T${blue_cp}"
#local smiley="%(?,%{$GREEN%}:%)%{$reset_color%},%{$RED%}:(%{$reset_color%})"
#PROMPT="╭”${path_p}”${user_host}”${ret_status}”${time}
#╰”${blue_op}${smiley}${blue_cp} > "
#local cur_cmd="${NORMAL}%_${NORMAL}"
#PROMPT2="${cur_cmd}> "


if [[ `whoami` == root ]]; then

PS1="†”[%{$RED%}%n%{$NORMAL%}@%{$TEST%}%m %30<...< %{$NORMAL%}%~]%(!.#.%\$) 
 ” %{$RED%}%T%{$NORMAL%}> "

else

PS1="†”[%{$GREEN%}%n%{$NORMAL%}@%{$TEST%}%m %30<...< %{$NORMAL%}%~]%(!.#.%\$) 
 ” %{$GREEN%}%T%{$NORMAL%}> "
fi

#alias
export GREP_COLOR=32
alias grep='grep --colour=auto'
alias egrep='egrep --color'
alias ls='ls --color=auto --classify $*'
alias rd='rmdir'
alias md='mkdir'
alias ...='../..'
alias -g M="| more"
alias -g H="| head"
alias -g T="| tail"
alias -g G="| grep"
alias -g L="| less"
alias df="df -h -x supermount"
alias rm="rm -iv"
alias mv="mv -v"
alias cp='cp -v'
alias cls="clear"
alias cal="calendar -m"
alias packettracer=/usr/local/PacketTracer51/packettracer
alias d='du -s *|sort -n'
alias df='df -T --si -xtmpfs -xusbfs |sort'


#- Auto open certain files, just type file name 
alias -s {jpg,JPG,jpeg,JPEG,png,PNG,gif,GIF}='gqview'
alias -s {mpg,mpeg,avi,ogm,wmv,m4v,mp4,mov}='gmplayer'
alias -s {mp3,ogg,wav,flac}='gmplayer'
alias -s {html,php,com,net,org,gov,be}='firefox'
alias -s txt='vim'
alias -s {pdf,PDF}='epdfview'
alias -s pl='perl'

#completions
#General completion technique
#complete as much u can ..
zstyle ':completion:*' completer _complete _list _oldlist _expand _ignored _match _correct _approximate _prefix

zstyle ':completion:*' add-space true

zstyle ':completion:*' expand prefix suffix

#determine in which order the names (files) should be
#listed and completed when using menu completion.
#`size' to sort them by the size of the file
#`links' to sort them by the number of links to the file
#`modification' or `time' or `date' to sort them by the last modification time
#`access' to sort them by the last access time
#`inode' or `change' to sort them by the last inode change time
#`reverse' to sort in decreasing order
#If the style is set to any other value, or is unset, files will be
#sorted alphabetically by name.
zstyle ':completion:*' file-sort name
zstyle ':completion:*' group-name ''
zstyle ':completion:*' insert-unambiguous true
zstyle ':completion:*' list-prompt '%SAt %p: Hit TAB for more, or the character to insert%s'
zstyle ':completion:*' list-suffixes true
zstyle ':completion:*' matcher-list ''

#how many completions switch on menu selection
#use 'long' to start menu compl. if list is bigger than screen
#or some number to start menu compl. if list has that number
#of completions (or more).
zstyle ':completion:*' menu select=long
zstyle ':completion:*' original true
zstyle ':completion:*' select-prompt '%SScrolling active: current selection at %p%s'
zstyle ':completion:*' verbose true
zstyle :compinstall filename '$HOME/.zshrc'

#add colors to completions
zstyle ':completion:*:default' list-colors ${(s.:.)LS_COLORS}

#don't complete backup files as executables
zstyle ':completion:*:(all-|)files' ignored-patterns '*\~'
zstyle ':completion:*:cd:*' ignored-patterns '*\~'

#don't complete some "users" in chown
zstyle ':completion:*:*:*:users' ignored-patterns adm apache bin daemon games gdm halt ident junkbust lp mail mailnull named news nfsnobody nobody nscd ntp operator pcap postgres radvd  rpc rpcuser rpm shutdown squid sshd sync uucp vcsa xfs backup  bind dictd  gnats  identd  irc  man  messagebus  postfix  proxy  sys  www-data ftp http libuuid haldaemon polkituser stats wesnothd


zstyle ':completion:*:messages' format $'%{\e[0;31m%}%d%{\e[0m%}'
zstyle ':completion:*:warnings' format $'%{\e[0;31m%}No matches for: %d%{\e[0m%}'
zstyle ':completion:*:corrections' format $'%{\e[0;31m%}%d (errors: %e)%{\e[0m%}'
zstyle ':completion:*' group-name ''

#zstyle ':completion:*:*:cd:*:directory-stack' menu yes select #complete 'cd -<tab>' with menu

#show type of completion, show all kind of posible completion [ex allias or commmand]
zstyle ':completion:*:descriptions'    format $'%{\e[0;32m%}completing %B%d%b%{\e[0m%}'
#completions for small and big letters
zstyle ':completion:*'                 matcher-list 'm:{a-z}={A-Z}'

#menu for completion, choose completion with cursors keys, show menu for 5 or more completions
zstyle ':completion:*'                 group-name ''
if [[ -z "$NOMENU" ]] ; then
    zstyle ':completion:*'               menu select=5
else
    setopt no_auto_menu # don't use any menus at all
fi

#provide verbose completions
zstyle ':completion:*'                 verbose true

#kill looks better with menu
zstyle ':completion:*:kill:*' command 'ps -u $USER -o pid,%cpu,tty,cputime,cmd'
zstyle ':completion:*:kill:*' insert-ids single
zstyle ':completion:*:*:kill:*' menu yes select
zstyle ':completion:*:kill:*' force-list always
zstyle ':completion:*' menu select=long-list select=1

#sections in man
zstyle ':completion:*' separate-sections true

#set some options
setopt append_history #when exiting, append history entries to $HISTFILE, rather than replacing the old file; this is the default
setopt share_history #always import new commands from $HISTFILE
setopt hist_ignore_all_dups #ignore iteration commmand in history file
setopt hist_ignore_space #if the commandline starts with a whitespace, don't add it to history
setopt extended_history #save additional info to $HISTFILE
setopt auto_cd ## change to directory without "cd"
setopt no_beep #beeper=off ;)
#setopt correctall #try to correct every word, dangerous with some commands (e.g. mv)
setopt correct #try to correct the spelling of commands
setopt notify #report status of background jobs immediately
setopt nohup #zsh don't kill off all background jobs when logout
setopt extended_glob #you want zsh's extended globbing features. Set this one, Luke!
setopt print_exit_value #if program ends with exit code !0, code will be print
setopt hist_reduce_blanks
setopt no_list_ambiguous
setopt no_list_beep 
setopt list_packed 
setopt glob_complete 
#setopt transient_rprompt

# Display path in titlebar of terms.
[[ -t 1 ]] || return
     case $TERM in
            *xterm*|*rxvt*|(dt|k|E)term)
                   precmd() {
                    print -Pn "\e]2;[%n] : [%m] : [%~]\a"
                       }
              preexec() {
                print -Pn "\e]2;[%n] :[%m] : [%~] :  [$1] \a"
             }
           ;;
    esac

# new grub-splash in 5sec
create-grub-splash() {
    if [[ $# != "0" ]]; then
        for image in $* ; do
            convert ${image} -resize 640x480 -colors 14 -depth 8 ${image%.png}.xpm.gz
         done
     else
        die "Not enough arguments"                
    fi
}

autoload zmv
# no more files with space in the name

space_rm() {
    for file in *; do 
         zmv ${file} ${file:gs/\ /_/}
    done
}

#say bye to files with upper characters in the name
lowercase_mv() {
     for file in *; do
        zmv $file ${file//(#m)[A-Z]/${(L)MATCH}}
    done
}

# set colors for GNU ls ; set this to right file /switch beetwen green and blue dirs color
#eval `dircolors /etc/DIR_COLORS`

# tetris, press control+t to play
autoload -U tetris
zle '-N' tetris
bindkey "^T" tetris

# find process to kill and kill it.
pskill ()
{ 
    local pid
    pid=$(ps -ax | grep $1 | grep -v grep | awk '{ print $1 }')
    echo -n "killing $1 (process $pid)..."
    kill -9 $=pid
    echo "slaughtered."
}

## add colors to processes for kill completion
#zstyle ':completion:*:*:kill:*:processes' list-colors '=(#b) #([0-9]#)*=00;33=01;31'

#mount dvd
mdvd ()
{
    local mounted
    local cpwd
    mounted=$(grep dvd /etc/mtab)
    if [[ $mounted = "" ]];then
        sudo mount /media/dvd
        echo "-- mounted dvdrom --"
        cd /media/dvd ; ls
        else
        cpwd=$(pwd|grep cdrom)
                if [[ $cpwd = "" ]];then
                    umount /media/dvd
            echo "-- umounted dvdrom --"
            else
            cd;umount /media/dvd
            echo "-- umounted dvdrom --"
            pwd 
        fi  
    fi
}

zstyle -e ':completion:*' special-dirs '[[ $PREFIX = (../)#(|.|..) ]] && reply=(..)'

# display some system info
status() {
    print ""
    print "Date..: "$(date "+%Y-%m-%d %H:%M:%S")""
    print "Shell.: Zsh $ZSH_VERSION (PID = $$, $SHLVL nests)"
    print "Term..: $TTY ($TERM), $BAUD bauds, $COLUMNS x $LINES cars"
    print "Login.: $LOGNAME (UID = $EUID) on $HOST"
    print "System: $(cat /etc/[A-Za-z]*[_-][rv]e[lr]*)"
    print "Uptime:$(uptime)"
    print ""
}

#colors
if [[ -f ~/.dir_colors ]]; then
    eval `dircolors -b ~/.dir_colors`
else
    if [[ -f /etc/DIR_COLORS ]]; then
    eval `dircolors -b /etc/DIR_COLORS`
    fi
fi

#ls -l /dev Im<space> gets replaced by zsh% ls -l /dev | more

typeset -Ag abbreviations
abbreviations=(
  "Im"    "| more"
  "Ia"    "| awk"
  "Ig"    "| grep"
  "Ieg"   "| egrep"
  "Iag"   "| agrep"
  "Igr"   "| groff -s -p -t -e -Tlatin1 -mandoc"
  "Ip"    "| $PAGER"
  "Ih"    "| head"
  "Ik"    "| keep"
  "It"    "| tail"
  "Is"    "| sort"
  "Iv"    "| ${VISUAL:-${EDITOR}}"
  "Iw"    "| wc"
  "Ix"    "| xargs"
)

magic-abbrev-expand() {
local MATCH
LBUFFER=${LBUFFER%%(#m)[_a-zA-Z0-9]#}
LBUFFER+=${abbreviations[$MATCH]:-$MATCH}
zle self-insert
}

no-magic-abbrev-expand() {
LBUFFER+=' '
}

zle -N magic-abbrev-expand
zle -N no-magic-abbrev-expand
bindkey " " magic-abbrev-expand
bindkey "^x " no-magic-abbrev-expand

google() {
    local str opt
        if [ $# != 0 ]; then
            for i in $*; do
                str="$str+$i"
            done
        str=`echo $str | sed 's/^\+//'` 
        opt='search?rls=pl&ie=utf-8&oe=utf-8'
        opt="${opt}&q=${str}"
          fi
echo "http://www.google.pl/${opt}"
}


extract_archive () {
   local old_dirs current_dirs lower
   lower=${(L)1}
   old_dirs=( *(N/) )
   if [[ $lower == *.tar.gz || $lower == *.tgz ]]; then
        tar zxfv $1
   elif [[ $lower == *.gz ]]; then
        gunzip $1
   elif [[ $lower == *.tar.bz2 || $lower == *.tbz ]]; then
        bunzip2 -c $1 | tar xfv -
   elif [[ $lower == *.bz2 ]]; then
        bunzip2 $1
   elif [[ $lower == *.zip ]]; then
        unzip $1
   elif [[ $lower == *.rar ]]; then
        unrar e $1
   elif [[ $lower == *.tar ]]; then
        tar xfv $1
   elif [[ $lower == *.tgz ]]; then
     gunzip -d $1
   elif [[ $lower == *.tbz2 ]]; then     
     tar -jxvf $1
   elif [[ $lower == *.lha ]]; then
        lha e $1
   elif [[ $lower == *.7z ]]; then
    7z x $1
   elif [[ $lower == *.Z ]]; then
    uncompress $1
   else
        print "Unknown archive type: $1"
        return 1
  fi
# Change in to the newly created directory, and list the directory contents, if there is one.
current_dirs=( *(N/) )
for i in {1..${#current_dirs}}; do
      if [[ $current_dirs[$i] != $old_dirs[$i] ]]; then
          cd $current_dirs[$i]
            ls
         break
     fi
done
   }
alias ex=extract_archive
compdef '_files -g "*.gz *.tgz *.bz2 *.tbz *.zip *.rar *.tar *.lha"' extract_archive

#run fluxbox when user login on tty1
if [ -z "$DISPLAY" ] && [ $(tty) = /dev/tty1 ]; then
    startx
fi

#most useless function in zsh, it draws Mandelbrot fractal :)
function most_useless_use_of_zsh {
    local lines columns colour a b p q i pnew
     ((columns=COLUMNS-1, lines=LINES-1, colour=0))
     for ((b=-1.5; b<=1.5; b+=3.0/lines)) do
         for ((a=-2.0; a<=1; a+=3.0/columns)) do
            for ((p=0.0, q=0.0, i=0; p*p+q*q < 4 && i < 32; i++)) do
               ((pnew=p*p-q*q+a, q=2*p*q+b, p=pnew))
            done
                 ((colour=(i/4)%8))
                echo -n "\\e[4${colour}m " 
            done
            echo
        done
     }

#set colors in letters when hit the tab [no idea how write this simpler]
setopt extended_glob
highlights='${PREFIX:+=(#bi)($PREFIX:t)(?)*==31=1;32}':${(s.:.)LS_COLORS}}
zstyle -e ':completion:*' list-colors 'reply=( "'$highlights'" )'
unset highlights

zstyle ':completion:*' remove-all-dups true
zstyle ':completion:*' use-cache true


#zstyle ':completion:*:descriptions' format '%B%d%b'
#zstyle ':completion:*:corrections' format '%B%d (błędy: %e)%b'
#zstyle ':completion:*:messages' format '%d'
#zstyle ':completion:*:warnings' format '%BNic nie znaleziono dla: %d%b'


# Print out current calendar with highlighted day
calendar() {
if [[ ! -f /usr/bin/cal ]] ; then
echo "Please install cal before trying to use it!"
return
fi

    if [[ "$#" = "0" ]] ; then
        /usr/bin/cal | egrep -C 40 --color "\<$(date +%e| tr -d ' ')\>"
    else
        /usr/bin/cal $@ | egrep -C 40 --color "\<($(date +%B)|$(date +%e | tr -d ' '))\>"
    fi
}

#- Create archive, usage $roll 'archive-name.zip 'archive-folder'
roll() {
    if [ -n "$1" ] ; then
        FILE=$1
        case $FILE in
             *.tar.bz2) shift && tar cjf $FILE $* ;;
             *.tar.gz) shift && tar czf $FILE $* ;;
             *.tgz) shift && tar czf $FILE $* ;;
             *.zip) shift && zip $FILE $* ;;
             *.rar) shift && rar $FILE $* ;;
        esac
    else
        echo "You must specify a filename."
    fi
}

#- Determine a directory sizes
dirsize() {
    du -shx * .[a-zA-Z0-9_]* 2> /dev/null | egrep '^ *[0-9.]*[MG]' | sort -n > ~/tmp/list
    egrep '^ *[0-9.]*M' ~/tmp/list
    egrep '^ *[0-9.]*G' ~/tmp/list
    rm -rf ~/tmp/list &> /dev/null
}

zipdir() { zip "$@".zip -r "$@" -x "*/.DS_Store" "*/.svn/*" }