Forum Debian Users Gang

awk '{print $1}' /proc/modules

/usr/src/linux/scripts/ver_linux

#!/usr/bin/awk -f
# SPDX-License-Identifier: GPL-2.0
# Before running this script please ensure that your PATH is
# typical as you use for compilation/installation. I use
# /bin /sbin /usr/bin /usr/sbin /usr/local/bin, but it may
# differ on your system.

BEGIN {
    usage = "If some fields are empty or look unusual you may have an old version.\n"
    usage = usage "Compare to the current minimal requirements in Documentation/Changes.\n"
    print usage

    system("uname -a")
    printf("\n")

    vernum = "[0-9]+([.]?[0-9]+)+"
    libc = "libc[.]so[.][0-9]+$"
    libcpp = "(libg|stdc)[+]+[.]so([.][0-9]+)+$"

    printversion("GNU C", version("gcc -dumpversion"))
    printversion("GNU Make", version("make --version"))
    printversion("Binutils", version("ld -v"))
    printversion("Util-linux", version("mount --version"))
    printversion("Mount", version("mount --version"))
    printversion("Module-init-tools", version("depmod -V"))
    printversion("E2fsprogs", version("tune2fs"))
    printversion("Jfsutils", version("fsck.jfs -V"))
    printversion("Reiserfsprogs", version("reiserfsck -V"))
    printversion("Reiser4fsprogs", version("fsck.reiser4 -V"))
    printversion("Xfsprogs", version("xfs_db -V"))
    printversion("Pcmciautils", version("pccardctl -V"))
    printversion("Pcmcia-cs", version("cardmgr -V"))
    printversion("Quota-tools", version("quota -V"))
    printversion("PPP", version("pppd --version"))
    printversion("Isdn4k-utils", version("isdnctrl"))
    printversion("Nfs-utils", version("showmount --version"))
    printversion("Bison", version("bison --version"))
    printversion("Flex", version("flex --version"))

    while ("ldconfig -p 2>/dev/null" | getline > 0)
        if ($NF ~ libc || $NF ~ libcpp)
            if (!seen[ver = version("readlink " $NF)]++)
                printversion("Linux C" ($NF ~ libcpp? "++" : "") " Library", ver)

    printversion("Dynamic linker (ldd)", version("ldd --version"))
    printversion("Procps", version("ps --version"))
    printversion("Net-tools", version("ifconfig --version"))
    printversion("Kbd", version("loadkeys -V"))
    printversion("Console-tools", version("loadkeys -V"))
    printversion("Sh-utils", version("expr --v"))
    printversion("Udev", version("udevadm --version"))
    printversion("Wireless-tools", version("iwconfig --version"))

    while ("sort /proc/modules" | getline > 0) {
        mods = mods sep $1
        sep = " "
    }
    printversion("Modules Loaded", mods)
}

function version(cmd,    ver) {
    cmd = cmd " 2>&1"
    while (cmd | getline > 0) {
        if (match($0, vernum)) {
            ver = substr($0, RSTART, RLENGTH)
            break
        }
    }
    close(cmd)
    return ver
}

function printversion(name, value,  ofmt) {
    if (value != "") {
        ofmt = "%-20s\t%s\n"
        printf(ofmt, name, value)
    }
}

If some fields are empty or look unusual you may have an old version.
Compare to the current minimal requirements in Documentation/Changes.

Linux gentoo 6.6.32-gentoo-dist #1 SMP PREEMPT_DYNAMIC Sat May 25 17:45:27 -00 2024 x86_64 Intel(R) Core(TM) i7-10700K CPU @ 3.80GHz GenuineIntel GNU/Linux

GNU C                   13
GNU Make                4.4.1
Binutils                2.42
Util-linux              2.39.3
Mount                   2.39.3
Module-init-tools       32
E2fsprogs               1.47.0
Bison                   3.8.2
Flex                    2.6.4
Linux C++ Library       6.0.32
Dynamic linker (ldd)    2.39
Procps                  4.0.4
Net-tools               2.10
Kbd                     2.6.4
Console-tools           2.6.4
Sh-utils                9.4
Udev                    254
Modules Loaded          8021q ac97_bus binfmt_misc cfg80211 crc32_pclmul crc32c_intel crct10dif_pclmul drm_ttm_helper e1000 fat garp ghash_clmulni_intel i2c_piix4 intel_rapl_common intel_rapl_msr joydev llc mrp pcspkr polyval_clmulni polyval_generic rapl rfkill serio_raw sha1_ssse3 sha256_ssse3 sha512_ssse3 snd snd_ac97_codec snd_intel8x0 snd_pcm snd_timer soundcore stp ttm vfat video vmwgfx wmi